mirror of
https://github.com/jart/cosmopolitan.git
synced 2024-05-05 21:28:46 +00:00
f4f4caab0e
I wanted a tiny scriptable meltdown proof way to run userspace programs and visualize how program execution impacts memory. It helps to explain how things like Actually Portable Executable works. It can show you how the GCC generated code is going about manipulating matrices and more. I didn't feel fully comfortable with Qemu and Bochs because I'm not smart enough to understand them. I wanted something like gVisor but with much stronger levels of assurances. I wanted a single binary that'll run, on all major operating systems with an embedded GPL barrier ZIP filesystem that is tiny enough to transpile to JavaScript and run in browsers too. https://justine.storage.googleapis.com/emulator625.mp4
116 lines
4.4 KiB
C
116 lines
4.4 KiB
C
/*-*- mode:unix-assembly; indent-tabs-mode:t; tab-width:8; coding:utf-8 -*-│
|
|
│vi: set et ft=asm ts=8 tw=8 fenc=utf-8 :vi│
|
|
╞══════════════════════════════════════════════════════════════════════════════╡
|
|
│ Copyright 2020 Justine Alexandra Roberts Tunney │
|
|
│ │
|
|
│ This program is free software; you can redistribute it and/or modify │
|
|
│ it under the terms of the GNU General Public License as published by │
|
|
│ the Free Software Foundation; version 2 of the License. │
|
|
│ │
|
|
│ This program is distributed in the hope that it will be useful, but │
|
|
│ WITHOUT ANY WARRANTY; without even the implied warranty of │
|
|
│ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU │
|
|
│ General Public License for more details. │
|
|
│ │
|
|
│ You should have received a copy of the GNU General Public License │
|
|
│ along with this program; if not, write to the Free Software │
|
|
│ Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA │
|
|
│ 02110-1301 USA │
|
|
╚─────────────────────────────────────────────────────────────────────────────*/
|
|
#ifndef APE_IDATA_H_
|
|
#define APE_IDATA_H_
|
|
#ifdef __ASSEMBLER__
|
|
#include "ape/relocations.h"
|
|
/* clang-format off */
|
|
|
|
/ Links function from external DLL.
|
|
/
|
|
/ This embeds a function pointer in the binary. The NT Executive
|
|
/ fills its value before control is handed off to the program.
|
|
/
|
|
/ @note only ELF toolchains are powerful enough to use this
|
|
/ @see libc/nt/master.sh
|
|
/ @see ape/ape.lds
|
|
/ @see winimp
|
|
.macro .imp dll:req fn:req actual:req hint
|
|
.dll \dll
|
|
.section .piro.data.sort.iat.2.\dll\().2.\actual,"aw",@progbits
|
|
.type \fn,@object
|
|
.align __SIZEOF_POINTER__
|
|
\fn: .quad RVA((\dll\().\actual))
|
|
.size \fn,.-\fn
|
|
.globl \fn
|
|
.hidden \fn
|
|
.previous
|
|
.section .idata.ro.ilt.\dll\().2.\actual,"a",@progbits
|
|
.Lidata.ilt.\dll\().\actual:
|
|
.quad RVA((\dll\().\actual))
|
|
.type .Lidata.ilt.\dll\().\actual,@object
|
|
.size .Lidata.ilt.\dll\().\actual,.-.Lidata.ilt.\dll\().\actual
|
|
.previous
|
|
.section .idata.ro.hnt.\dll\().2.\actual,"a",@progbits
|
|
\dll\().\actual:
|
|
.ifnb \hint # hint i.e. guess function ordinal
|
|
.short \hint
|
|
.else
|
|
.short 0
|
|
.endif
|
|
.asciz "\actual"
|
|
.align 2 # documented requirement
|
|
.globl \dll\().\actual
|
|
.hidden \dll\().\actual
|
|
.type \dll\().\actual,@object
|
|
.size \dll\().\actual,.-\dll\().\actual
|
|
.previous
|
|
.endm
|
|
|
|
/ Defines DLL import.
|
|
/ @note this is an implementation detail of .imp
|
|
.macro .dll name:req
|
|
.section .idata.ro.idt.2.\name,"aG",\name,comdat
|
|
.equ .Lidata.idt.\name,.
|
|
.long RVA(idata.ilt.\name) # ImportLookupTable
|
|
.long 0 # TimeDateStamp
|
|
.long 0 # ForwarderChain
|
|
.long RVA(.Lidata.str.\name) # DllNameRva
|
|
.long RVA(idata.iat.\name) # ImportAddressTable
|
|
.type .Lidata.idt.\name,@object
|
|
.size .Lidata.idt.\name,.-.Lidata.idt.\name
|
|
.previous
|
|
.section .idata.ro.ilt.\name\().1,"aG",\name,comdat
|
|
.align __SIZEOF_POINTER__
|
|
.type idata.ilt.\name,@object
|
|
idata.ilt.\name:
|
|
.previous/*
|
|
...
|
|
decentralized content
|
|
...
|
|
*/.section .idata.ro.ilt.\name\().3,"aG",\name,comdat
|
|
.quad 0
|
|
.previous
|
|
.section .idata.ro.hnt.\name\().1,"aG",\name,comdat
|
|
.align __SIZEOF_POINTER__
|
|
.type idata.hnt.\name,@object
|
|
.equ idata.hnt.\name,.
|
|
.previous
|
|
.section .piro.data.sort.iat.2.\name\().1,"awG",\name,comdat
|
|
.align __SIZEOF_POINTER__
|
|
.type idata.iat.\name,@object
|
|
idata.iat.\name:
|
|
.previous/*
|
|
...
|
|
decentralized content
|
|
...
|
|
*/.section .piro.data.sort.iat.2.\name\().3,"awG",\name,comdat
|
|
.quad 0
|
|
.previous
|
|
.pushsection .rodata.str1.1,"aSM",@progbits,1
|
|
.Lidata.str.\name:
|
|
.asciz "\name\().dll"
|
|
.popsection
|
|
.endm
|
|
|
|
/* clang-format on */
|
|
#endif /* __ASSEMBLER__ */
|
|
#endif /* APE_IDATA_H_ */
|